intdupla.mws

Integrais Duplas

Rui Marcos de O. Barros

Departamento de Matemática

Universidade Estadual de Maringá

rmobarros@uem.br

Integrais Duplas

Vamos nesta seção definir rapidamente o que é uma integral dupla de uma função em um certo domínio R contido em R^2 . Para isso vamos relembrar dois tipos básicos de regiões do plano R^2 .

Definição: Uma região será dita ser do tipo R[x] se a região for limitada lateralmente por retas x = a e x = b , inferiormente por uma curva y = g[1](x) e superiormente por uma curva y = g[2](x) .

Um exemplo de uma região do tipo R[x] é a região limitada pelas curvas x = -2 , x = 5 , y = sin(x) e y = 1/2*x+2 . Podemos ilustrar essa região com os seguintes comandos:

> restart:
with(plots):
with(plottools):

g1:=x->sin(x);
g2:=x->(1/2)*x+2;

l1:=implicitplot(x=-2,x=-2..-1,y=g1(-2)..g2(-2),color=green):
l2:=implicitplot(x=5,x=4..6,y=g1(5)..g2(5),color=green):
grf:=plot([g1(x),g2(x)],x=-2..5,color=[red,blue]):

display(grf,l1,l2);



Warning, the name changecoords has been redefined

g1 := sin

g2 := proc (x) options operator, arrow; 1/2*x+2 end...

[Maple Plot]

>

Definição: Uma região será dita ser do tipo R[y] se a região for limitada inferior e superiormente por retas y = c e y = d , e lateralmente por curvas x = h[1](y) e x = h[2](y) .

Um exemplo de uma região do tipo R[y] é a região limitada pelas curvas y = 3 , eixo dos "xx" , x = sqrt(y) e x = -3/2*y+7 . Podemos ilustrar esta região. Como para a função x = sqrt(y) a variável x só assume valores positivos podemos usar o comando implicitplot com variação de y sempre entre 0 e 3 para sabermos qual é a região.

> g1:=implicitplot(x=sqrt(y),x=0..100,y=0..3,color=red):
g2:=implicitplot(x=-3*y/2+7,x=0..100,y=0..3,color=blue):
display(g1,g2);

[Maple Plot]

>

Como a ilustração não apresenta valores de x maiores que 7 devemos prestar atenção ao fato de que na função x = -3*y/2+7 quando y = 0 temos x = 7 . Quando y = 3 as funções assumem valores sqrt(3) e 5/2 respectivamente. Assim podemos ilustar a região completando a ilustração anterior com segmentos de altura y = 3 e y = 0.

> l1:=plot(3,x=sqrt(3)..5/2,color=green):
l2:=plot(0,x=0..7,color=green,thickness=3):
display(g1,g2,l1,l2);

[Maple Plot]

>

Considere uma região Q contida em R^2 . Por uma partição puntuada P de Q entendemos um conjunto de subretângulos P[i,j] contidos na região Q e um conjunto A de pontos A[i,j] cada um destes contido no respectivo subretângulo P[i,j] .

Chamamos de norma da partição P ao comprimento da maior diagonal dentre todas as diagonais de todos os subretângulos de P.

Se uma função contínua z = f(x,y) for definida na região Q, podemos construir a soma de Riemann de f associada a partição P como sendo

Sum(f(A[i,j])*Delta[ij],P) ,

onde a somatória é sobre todos os subretângulos de P e Delta[ij] denota a área da subretângulo P[i,j] .

Esta soma de Riemann aproxima a o volume da região limitada pelo plano xy e o gráfico da função z = f(x,y) definida sobre a região Q.

Vejamos uma ilustração deste fato considerando a função z = exp(-x^2+y^2) definida sobre a região Q=[-1,1]x[0,1] .

Primeiramente o gráfico da função sobre este domínio é mostrado abaixo.

> plot3d(exp(-x^2+y^2),x=-1..1,y=0..1,style=patch,axes=boxed);

[Maple Plot]

>

Para ilustrar que a soma de Riemann aproxima o volume limitado entre o gráfico e o plano "xy" vamos carregar uma rotina. Para isso basta compilar a célula abaixo.

> soma3d:= proc(f,a,b,c,d,m,n)
local deltax,deltay,subret,graf,i,j :
deltax:=(b-a)/m:
deltay:=(d-c)/n:
subret:=array(1..m,1..n):
with(plots):with(plottools):
graf:=plot3d(f(x,y),x=a..b,y=c..d,style=wireframe):
for i from 1 to m do
for j from 1 to n do
subret[i,j]:=display(cuboid([a+(i-1)*deltax,c+(j-1)*deltay,0],[a+(i)*deltax,c+(j)*deltay,evalf(f(a+(i)*deltax,c+(j)*deltay))],color=grey,style=line)):
od:
od:
display(graf,seq(seq(subret[r,s],r=1..m),s=1..n));
end:

>

Agora usamos o comando soma3d( função, a, b, c, d, m, n ) . Nesta sintaxe a função já deve estar previamente definida. Os quatro números seguintes são os que definem o domínio [a,b]X[c,d] e os dois últimos números m e n são os que definem respectivamente em quantas subdivisões os intervalos [a,b] e [c,d] serão particionados.

Para este primeiro exemplo a partição é feita subdividindo-se o domínio em 50 subretângulos. Para isto usamos m = 5 e n = 10 no final do comando.

Primeiramente definimos a função z .

> z:=(x,y)->exp(-x^2+y^2);

z := proc (x, y) options operator, arrow; exp(-x^2+...

>

Chamamos então a rotina soma3d com o domínio e as subdivisões já explicadas.

> soma3d(z,-1,1,0,1,5,10);

[Maple Plot]

>

Quanto maior for a quantidade de subretângulos maior será a aproximação do volume. Evidentemente o tempo de processamento será maior. Vejamos mais algumas aproximações:

> soma3d(z,-1,1,0,1,10,10);

[Maple Plot]

>

> soma3d(z,-1,1,0,1,20,15);

[Maple Plot]

>

O próximo comando usa uma partição com 900 subretângulos. Esteja ciente da demora na execução do comando em computadores com processadores mais lentos!

> soma3d(z,-1,1,0,1,30,30);

[Maple Plot]

>

Ao aumentarmos a quantidade de subretângulos estamos diminuindo a norma da partição já que esta é igual a medida da maior das diagonais dos subretângulos.

Definimos então a integral definida de f(x,y) sobre Q como limite (caso exista) da soma de Riemann quando a norma da partição P tende a zero.

int(int(f(x,y),x),y) = lim[proc (abs(P)) options op... .

Se a integral dupla de f sobre Q existe dizemos que f é integrável sobre Q. Pode-se provar que se f é contínua sobre Q então f é integrável sobre Q.

O cálculo de integrais duplas faz-se através de integrais iteradas.

Teorema 1: Seja Q uma região do tipo R[x] compreendida entre os gráficos de y = g[1](x) e y = g[2](x) , com g[1] e g[2] contínuas em [a,b]. Se f é contínua em Q então

int(int(f(x,y),x),y) = int(int(f(x,y),y = g[1](x) .... .

Teorema 2: Seja Q uma região do tipo R[y] compreendida entre os gráficos de x = h[1](y) e x = h[2](y) , com h[1] e h[2] contínuas em [c,d]. Se f é contínua em Q então

int(int(f(x,y),x),y) = int(int(f(x,y),x = h[1](y) .... .

Explicação: Na expressão int(int(f(x,y),y = g[1](x) .. g[2](x)),x = a .. b) calculamos primeiramente a integral int(f(x,y),y = g[1](x) .. g[2](x)) considerando a variável x da função f(x,y) como uma constante. O resultado desta integração é uma expressão w(x) envolvendo apenas a variável x , esta será então integrada através de int(w(x),x = a .. b) . Caso a região seja do tipo R[y] o cálculo da integral do teorema 2 será feito de modo análogo.

Os comandos do Maple para o cálculo de integrais duplas são bem naturais para o usuário que conhece o comando para cálculo de integrais simples.

Por exemplo, para calcular a integral int(int(sin(x*y),y = -x^2 .. 3*x+1),x = -2 .. 3) usa-se o comando abaixo.

> int(int(y*x^3-2*x,y=-x^2..3*x+1),x=-2..3);

2725/16

>

Caso se queira apenas escrever a integral sem efetuar os cálculos usa-se o comando abaixo.

> Int(Int(y*x^3-2*x,y=-x^2..3*x+1),x=-2..3);

Int(Int(y*x^3-2*x,y = -x^2 .. 3*x+1),x = -2 .. 3)

>

O valor do cálculo da integral pode ser pedido agora com o comando value(%) .

> value(%);

2725/16

>

Vamos ver como calculamos o volume de alguns sólidos limitados por superfícies.

Exemplo 1: Encontre o volume do sólido do primeiro octante delimitado pelos planos coordenados, pelo parabolóide z = x^2+y^2+1 e pelo plano 2*x+y = 2 . Para ver este exemplo clique aqui .

Exemplo 2: Encontre o volume do sólido que está no primeiro octante e é delimitado pelos três planos coordenados e pelos cilindros x^2+y^2 = 9 e y^2+z^2 = 9 . Para ver este exemplo clique aqui .

Exemplo 3: Encontre o volume do sólido limitado pelo parabolóide z = 4-x^2-y^2 e o plano z = 0 . Para ver este exemplo clique aqui .

Para resolver alguns exercícios clique aqui .

Área de Superfície (ver agora)